차동신호(Differential Signal)란? (2)

지난번에 차동신호(differential-mode signal)에 대하여 잠깐 설명하면서 공통신호(common-mode signal)도 짧게 언급하였다. 앞서 교류공통모드신호(AC common-mode signal)는 두 단일입력신호(single-ended signal)에 skew가 있을때 발생한다는 예를 들었는데 교류공통모드신호가 생기는 원인으로 다른 몇가지를 더 예로 들고자 한다.

 다음 각각의 그림에 보이는 신호들은 500mVp-p인 진폭과 상승시간과 하강시간이 각각 50psec인 신호(파란색과 노란색)를 50-Ohm으로 소스종단(termination)한 차동입력단자에 인가하여 250psec의 신호지연시간을 갖는 전송선(transmission line)을 통과한 후 측정한 차동모드(differential-mode) 전압(보라색)과 공통모드(common-mode) 전압(연두색)이다.

[그림 1]은 전송선(transmission line)출력단에서 측정한 공통모드(common-mode) 신호가 0V고 차동모드(differential-mode) 신호가 +/-500mVp-p인 신호이다.

[그림 1]

[그림 2]는 파란색 신호에 20psec의 skew로 인한 공통모드(common-mode) 신호이다. 공통모드(common-mode) 신호의 폭과 전압이 무려 14psec와 +/-100mV로 나타나며 차동모드(differential-mode) 전압의 10%와 90%부분에서 감쇄현상이 나타났다.

[그림 2]


[그림 3]은 진폭차이(amplitude imbalance)로 인한 공통모드(common-mode) 신호이다. 단일입력신호 Vp(파란색)는 소스에서 +/-500mV를 유지하고 Vn(노란색)은 입력단에서 약 +/-100mV를 줄여 +/-400mV를 인가하였다. 그 결과 +/-25mV의 전압을 갖는 공통모드(common-mode) 전압이 발생함과 동시에 그만큼 차동모드(differential-mode) 전압도 감소하여 원래 +/-500mV였던것이 +/-450mV로 감소 하였다.

 [그림3]

 [그림 4]는 상승하강시간의 차이(rise and fall time imbalance)로 인한 공통모드(common-mode) 신호이다. 단일입력신호(single-ended signal) Vp(파란색)의 하강시간과 Vn(노란색)의 상승시간이 20psec정도 더 느린 경우이다. 이런 경우 +/-75mV의  톱니파 공통모드(common-mode) 전압이 발생함을 알 수 있고 skew가 발생했을 때와 마찬가지로 차동모드(differential-mode) 전압의 10%와 90%부분에서 감쇄현상이 나타났다.

[그림 4]


밑에 보이는 스크립트는 위에서 보여진 common-mode signal을 시뮬레이션한 HSpice deck이다.

*Common Mode Tline
*
*

.PARAM LV=-0.5 HV=0.5 TD=10p TR=50p TF=50p TPW=0.9n TPER=2n

*Normal
Vindiff1 vp_src 0 PULSE LV HV TD TR TF TPW TPER
Vindiff2 vn_src 0 PULSE HV LV TD TR TF TPW TPER

*Skew
*Vindiff1 vp_src 0 PULSE LV HV TD TR TF TPW TPER
*Vindiff2 vn_src 0 PULSE HV LV 'TD+20p' TR TF TPW TPER

*Amplitude Imbalance
*Vindiff1 vp_src 0 PULSE LV HV TD TR TF TPW TPER
*Vindiff2 vn_src 0 PULSE 'HV-0.1' 'LV+0.1' TD TR TF TPW TPER

*TrTf Imbalance
*Vindiff1 vp_src 0 PULSE LV HV TD TR 'TF+20p' TPW TPER
*Vindiff2 vn_src 0 PULSE HV LV TD 'TR+20p' TF TPW TPER

Rin1 vp_src vp_in 50
Rin2 vn_src vn_in 50

TP0 vp_in 0 VP 0 Z0=50 TD=250p
TN0 vn_in 0 VN 0 Z0=50 TD=250p

RTP VP 0 50
RTN VN 0 50

.OPTIONS accurate post=2 probe
.TRAN 1p 4n
.PROBE v(VP) v(VN)
.PROBE Vcm=par('(v(VP)+v(VN))/2') Vdiff=par('(v(VP)-v(VN))')

.END



This work is licensed under a Creative Commons Attribution-NonCommercial 3.0 Unported License.